XMLファイルの内容をオブジェクトにする

XMLの構造はツリー構造です。フォルダ構造とほぼ同じなのでフォルダのPAHTを記載するようにデータにアクセスします。

例えばPATHをオブジェクト風に記載すると以下のようになります。
・PATH
C:/Users/test/Desktop/test
↓
・オブジェクト風
pathObj.Users.test.Desktop.test

では実際にpowershellを利用しXMLをオブジェクト化します。
以下のサンプルXMLをデスクトップにtest.xmlファイルとして保存してください。

サンプルXML

<TestList version="2" revision="1">
	<Item category="test">
		<ID type="int">1</ID>
		<Name type="string">テスト1</Name>
		<Description type="text">テスト1の内容</Description>
		</Item>
	<Item category="test">
		<ID type="int">2</ID>
		<Name type="string">テスト2</Name>
		<Description type="text">テスト2の内容</Description>
	</Item>
	<Item category="test">
		<ID type="int">3</ID>
		<Name type="string">テスト3</Name>
		<Description type="text">テスト3の内容</Description>
	</Item>
	<Item category="news">
		<ID type="int">4</ID>
		<Name type="string">ニュース1</Name>
		<Description type="text">ニュース1の内容</Description>
	</Item>
	<Item category="news">
		<ID type="int">5</ID>
		<Name type="string">ニュース2</Name>
		<Description type="text">ニュース2の内容</Description>
	</Item>
	<Item category="news">
		<ID type="int">6</ID>
		<Name type="string">ニュース3</Name>
		<Description type="text">ニュース3の内容</Description>
	</Item>
</TestList>

コードを記載するためtest.ps1ファイルを作成します。

test.ps1を右クリック→編集をクリックしファイルを開きます。
以下のコードをコピペします。

# 現在のパス取得
$scriptPath = [System.IO.Path]::GetDirectoryName($myInvocation.MyCommand.Definition)

# xmlファイルのPATH
$source = "$scriptPath\test.xml"

# xmlオブジェクト作成
$xmlObj = (Get-Content -path "$source")
# データはループさせて取得
foreach ($List in $xmlObj.TestList) {
        foreach ($item in $List.Item) {
            echo $item.Name.innerText
        }
}

説明

1.オブジェクト化

$scriptPath = [System.IO.Path]::GetDirectoryName($myInvocation.MyCommand.Definition)
$source = "$scriptPath\test.xml"
$xmlObj = (Get-Content -path "$source")

XMLファイルをオブジェクト化するためXMLファイルのPATHを取得します。
ファイルのデータを一行づつ取得するGet-Contentコマンドに使用します。これでは普通テキストファイルのような処理になっていまいますのでXMLを扱えるように全体をXMLにキャストします。

2.要素の値を取得

foreach ($List in $xmlObj.TestList) {
    foreach ($item in $List.Item) {
       echo $item.Name.innerText
    }
}

要素の値を取得する場合はinnerTextプロパティを使用します。
オブジェクト.innerText
 

3.属性の値を取得

foreach ($List in $xmlObj.TestList) {
    foreach ($item in $List.Item) {
       echo $item.GetAttribute("category")
    }
}

属性の値を取得する場合はGetAttributeメソッドを使用します。
オブジェクト.GetAttribute(“属性名”)

特定の条件により処理する

if文を利用し特定の条件にマッチした値のみ取得します。
例ではItemのcategory属性の値が「test」になっている要素の値を取得します。

# 現在のパス取得
$scriptPath = [System.IO.Path]::GetDirectoryName($myInvocation.MyCommand.Definition)

# xmlファイルのPATH
$source = "$scriptPath\test.xml"

# xmlオブジェクト作成
$xmlObj = (Get-Content -path "$source")
# データはループさせて取得
foreach ($List in $xmlObj.TestList) {
        foreach ($item in $List.Item) {
            if($item.GetAttribute("category") -eq "test"){
             echo $item.Name.innerText
             }
        }
}

Windows10 バージョン確認

winver

adminユーザー有効化

net user administrator /active:yes

adminパスワード設定

net user administrator パスワード

ドメイン参加

wmic ComputerSystem WHERE "name='%computername%'" CALL JoinDomainOrWorkgroup Name="ドメイン名" Username="ドメイン管理者ユーザー" 
Password="パスワード" FJoinOptions=3

拡張子表示(再起動後反映)

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "HideFileExt" /t REG_DWORD /d "0" /f

隠しファイル表示(再起動後反映)

reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Hidden" /t REG_DWORD /d "1" /f

ユーザーアカウント削除

コマンドではユーザーフォルダの削除ができないため手動のほうがいい。

compmgmt.msc

→アカウントを削除

OneDriveをオフ

gpedit.msc

コンピューター構成→管理用テンプレート→Windowsコンポーネント→OneDrive→使用できないようにする→有効

Windows Updateの自動更新解除設定

gpedit.msc

コンピューター構成→管理用テンプレート→Windowsコンポーネント→Windows Update → 自動更新を構成する→無効

コルナタ無効化

gpedit.msc

コンピューター構成→管理用テンプレート→Windowsコンポーネント→検索→Cortanaの許可する→無効

セキュリティとメンテナンス(メッセージオフ)

control.exe /name Microsoft.ActionCenter

セキュリティとメンテナンスの設定を変更 → チェックをすべて外す

システムアイコンオフ(位置情報、アクションセンター)

start ms-settings:taskbar

システムアイコンのオン/オフの切り替え

Windows Deffender 無効

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows Defender" /v "DisableAntiSpyware" /d "1" /t REG_DWORD /f

firewall 無効

netsh advfirewall set allprofiles state off

タスクバーpeople非表示

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\People" /v "PeopleBand" /t REG_DWORD /d "0" /f

通知とアクション非表示

rem 「windowsへようこそ」
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SubscribedContent-310093Enabled" /t REG_DWORD /d "0" /f
rem 「windowsヒントやおすすめ」
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SubscribedContent-338389Enabled" /t REG_DWORD /d "0" /f
rem 「アプリやその他の送信者」
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\PushNotifications" /v "ToastEnabled" /t REG_DWORD /d "0" /f

画面中央の切替通知表示

reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\IME\15.0\IMEJP\MSIME" /v "ShowImeModeNotification" /t REG_DWORD /d "0" /f

プライバシー設定

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d "0" /f
reg add "HKEY_CURRENT_USER\Control Panel\International\User Profile" /v "HttpAcceptLanguageOptOut" /t REG_DWORD /d "1" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SubscribedContent-338393Enabled" /t REG_DWORD /d "0" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SubscribedContent-353694Enabled" /t REG_DWORD /d "0" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Start_TrackProgs" /t REG_DWORD /d "0" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Input\TIPC" /v "Enabled" /t REG_DWORD /d "0" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Privacy" /v "TailoredExperiencesWithDiagnosticDataEnabled" /t REG_DWORD /d "0" /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\DeviceAccess\Global\{2297E4E2-5DBE-466D-A12B-0F8286F0D9CA}" /v "Value" /t REG_SZ /d "Deny" /f

windowsアップデート無効

rem WindowsUpdateの自動更新解除(レジストリ)
reg add HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate /v "DisableOSUpgrade" /t REG_DWORD /d 00000001 /f
reg add HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /v NoAutoUpdate /d 1 /t REG_DWORD /f

rem Winアップデートスケジュール無効化
schtasks /Change /DISABLE /TN "\Microsoft\Windows\WindowsUpdate\Scheduled Start"
schtasks /Change /DISABLE /TN "\Microsoft\Windows\WindowsUpdate\sih"

rem Winアップデートサービス停止
sc config wuauserv start= disabled
sc failure "wuauserv" reset=0 actions= ""/""/""
net stop wuauserv

不要アプリの削除

powershell起動
以下コマンドをコピペ

Get-AppxPackage Microsoft.3DBuilder | Remove-AppxPackage                     # 3D Builder
Get-AppxPackage king.com.CandyCrushSodaSaga | Remove-AppxPackage             # Candy Crush Soda Saga
Get-AppxPackage DolbyLaboratories.DolbyAccess | Remove-AppxPackage           # Dolby Access
Get-AppxPackage Facebook.Facebook | Remove-AppxPackage                       # Facebook
Get-AppxPackage Microsoft.ZuneMusic | Remove-AppxPackage                     # Groove ミュージック
Get-AppxPackage KeeperSecurityInc.Keeper | Remove-AppxPackage                # Keeper
Get-AppxPackage 828B5831.HiddenCityMysteryofShadows | Remove-AppxPackage     # Hidden City アイテム探しアドベンチャー(FCU以降)
Get-AppxPackage NAVER.LINE* | Remove-AppxPackage                             # LINE
Get-AppxPackage 7EE7776C.LinkedInforWindows | Remove-AppxPackage             # LinkedIn(FCU以降)
Get-AppxPackage Microsoft.MicrosoftSolitaireCollection | Remove-AppxPackage  # Microsoft Solitaire Collection
Get-AppxPackage Microsoft.OfficeLens | Remove-AppxPackage                    # Office Lens
Get-AppxPackage Microsoft.Office.OneNote | Remove-AppxPackage                # OneNote
Get-AppxPackage Microsoft.People | Remove-AppxPackage                        # People
Get-AppxPackage Microsoft.Print3D | Remove-AppxPackage                       # Print3D(CFU以降)
Get-AppxPackage flaregamesGmbH.RoyalRevolt2 | Remove-AppxPackage             # RoyalRevolt 2
Get-AppxPackage 89006A2E.AutodeskSketchBook | Remove-AppxPackage             # SketchBook(FCU以降)
Get-AppxPackage Microsoft.SkypeApp | Remove-AppxPackage                      # Skypeを始めよう
Get-AppxPackage SpotifyAB.SpotifyMusic | Remove-AppxPackage                  # Spotify(FCU以降)
Get-AppxPackage Microsoft.MicrosoftStickyNotes | Remove-AppxPackage          # Sticky Notes
Get-AppxPackage *Twitter | Remove-AppxPackage                                # Twitter
Get-AppxPackage Microsoft.Microsoft3DViewer | Remove-AppxPackage             # View 3D
Get-AppxPackage Microsoft.XboxApp | Remove-AppxPackage                       # Xbox(AU以降)
Get-AppxPackage Microsoft.XboxGameOverlay | Remove-AppxPackage               # Xbox(AU以降)
Get-AppxPackage Microsoft.XboxIdentityProvider | Remove-AppxPackage          # Xbox(AU以降)
Get-AppxPackage Microsoft.XboxSpeechToTextOverlay | Remove-AppxPackage       # Xbox(AU以降)
Get-AppxPackage Microsoft.MicrosoftOfficeHub | Remove-AppxPackage            # 新しいOffice を始めよう
Get-AppxPackage Microsoft.WindowsAlarms | Remove-AppxPackage                 # アラーム＆クロック
Get-AppxPackage Microsoft.WindowsCamera | Remove-AppxPackage                 # カメラ
Get-AppxPackage Microsoft.5220175982889 | Remove-AppxPackage                 # テレBing
Get-AppxPackage Microsoft.Getstarted | Remove-AppxPackage                    # ヒント／はじめに
Get-AppxPackage king.com.BubbleWitch3Saga | Remove-AppxPackage               # バブルウィッチ3(FCU以降)
Get-AppxPackage Microsoft.WindowsFeedbackHub | Remove-AppxPackage            # フィードバックHub
Get-AppxPackage Microsoft.MSPaint | Remove-AppxPackage                       # ペイント3D
Get-AppxPackage Microsoft.GetHelp | Remove-AppxPackage                       # 問い合わせ／ヘルプの表示
Get-AppxPackage Microsoft.WindowsSoundRecorder | Remove-AppxPackage          # ボイスレコーダー
Get-AppxPackage A278AB0D.MarchofEmpires | Remove-AppxPackage                 # マーチ オブ エンパイア
Get-AppxPackage Microsoft.WindowsMaps | Remove-AppxPackage                   # マップ
Get-AppxPackage *bing* | Remove-AppxPackage                                  # マネー、スポーツ、ニュース、天気
Get-AppxPackage microsoft.windowscommunicationsapps | Remove-AppxPackage     # メール、カレンダー
Get-AppxPackage Microsoft.Messaging | Remove-AppxPackage                     # メッセージング
Get-AppxPackage Microsoft.YourPhone | Remove-AppxPackage                     # スマホ同期／モバイル コンパニオン
Get-AppxPackage Microsoft.OneConnect | Remove-AppxPackage                    # モバイル通信プラン／有料Wi-Fi & 携帯ネットワーク

不要なサービス停止

sc config BTAGService start= disabled
sc config bthserv start= disabled
sc config DiagTrack start= disabled
sc config Fax start= disabled
sc config wlidsvc start= disabled
sc config PNRPAutoReg start= disabled
sc config WPDBusEnum start= disabled
sc config SensorDataService start= disabled
sc config SensrSvc start= disabled
sc config SensorService start= disabled
sc config TapiSrv start= disabled
sc config XboxGipSvc start= disabled
sc config XblAuthManager start= disabled
sc config XblGameSave start= disabled
sc config XboxNetApiSvc start= disabled
sc config WerSvc start= disabled
sc config DusmSvc start= disabled
sc config RetailDemo start= disabled
sc config wuauserv start= disabled

ときどきスタート画面におすすめを表示するを停止

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SystemPaneSuggestionsEnabled" /t REG_DWORD /d "0" /f

ストアアプリの自動ダウンロード/自動インストール(更新)を無効

reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\WindowsStore" /v "AutoDownload" /t REG_DWORD /d "4" /f

リモートデスクトップ接続「許可」

reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d "0" /f

WiFi無効

netsh interface set interface "Wi-Fi" disable

再起動

shutdown -r

今後随時追加していきます。

前回のつづき

コンピューター情報操作

「wmic computersystem」コマンドはコンピューター名、グループ名の編集、ドメイン参加などコンピューターの情報操作でき操作できるコマンドです。

・コンピューター名の変更
wmic computersystem where name="%computername%" call rename name="[新しいコンピュータ名]"

・グループ名の変更
wmic computersystem where name="%computername%" call joindomainorworkgroup name="[新しいグループ名]"

・ドメイン参加
wmic computersystem WHERE "name='%computername%'" CALL JoinDomainOrWorkgroup name="[ドメイン名]" username="[ユーザー名]" password="[パスワード]" FJoinOptions=3

ユーザー操作

「net user」コマンドはユーザー関連の操作行えるコマンドです。

・adminユーザー有効化
net user administrator /active:yes

・ユーザーパスワード変更
net user [username] [password]

セッション操作（パソコンやサーバに接続しているユーザー）

・セッション一覧表示
net session

・セッション切断
net session [切断したい\\コンピュータ名] /delete /y

レジストリ操作

レジストリはWindowsやアプリケーションの設定がまとめられているデータベースです。このコマンドを使ってPCのキッティングの自動化などでよく使います。

レジストリ追加

reg add [キー名] /v [設定したい値の名前] /d <値> /t <タイプ> /f

例 UACを無効
キー名:HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows Defender
設定したい値の名前:DisableAntiSpyware
値：1
タイプ：REG_DWORD

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows Defender" /v "DisableAntiSpyware" /d "1" /t REG_DWORD /f

例：令和対応
キー名:"HKLM\SYSTEM\CurrentControlSet\Control\Nls\Calendars\Japanese\Eras"
設定したい値の名前:"2019 05 01"
値："令和_令_Reiwa_R"
タイプ：REG_SZ

REG ADD HKLM\SYSTEM\CurrentControlSet\Control\Nls\Calendars\Japanese\Eras /v "2019 05 01" /t REG_SZ /d "令和_令_Reiwa_R"

レジストリ参照

reg query [キー名] /v [設定したい値の名前]

キー名:HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows Defender
確認した値の名前:DisableAntiSpyware

例 UACを無効

reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows Defender" /v "DisableAntiSpyware"

例：令和対応

reg query "HKLM\SYSTEM\CurrentControlSet\Control\Nls\Calendars\Japanese\Eras" /v "2019 05 01"

タスクスケジュール

「schtasks」はタスクスケジュールを操作するコマンドです。サーバを整理するときにタスクスケジュールを一覧でまとめたときに使いました。

タクス実行

schtasks /run /tn [タスク名]

タスク追加

例1

タスク名(/tn [タスク名])：admin
実行ユーザー(/RU [ユーザー名])：administrator
実行ユーザーパスワード(/RP [パスワード])：password
実行コマンド(/tr [コマンド]):C:\タスク実行\Command
スケジュール(/sc [頻度] /sd [開始日付] /st [開始時間] /ri [間隔] 1-599940 分)：一度 2100/01/01 00:00:00
上書き(/F)：あり
実行レベル(/rl [LIMITED/HIGHEST])：HIGHEST
遅延時間(/DELAY [時間]):なし

schtasks /create /tn "admin" /RU administrator /RP password /tr C:\タスク実行\Command /sc once /sd 2100/01/01 /st 00:00:00  /rl highest /F

例2

タスク名(/tn [タスク名])：shutdow
実行コマンド(/tr [コマンド]):C:\insouApp\POS\Shutdown.bat
スケジュール(/sc [頻度] /sd [開始日付] /st [開始時間] /ri [間隔] 1-599940 分)：毎日 03:00:00
上書き(/F)：なし

schtasks /create /tn "shutdown" /tr C:\insouApp\POS\Shutdown.bat /sc daily /st 03:00:00

スケジュール無効化

schtasks /Change /DISABLE /TN [タスク名]

スケジュール削除

SCHTASKS /Delete /TN [タスク名]

タスク追加

SCHTASKS /Query /TN [タスク名]

ネットワークインターフェース設定

「netsh interface」はネットワークインターフェースの設定するコマンドです。これもPCのキッティングの自動化などでよく使います。

IPV4インターフェース一覧

netsh interface ipv4 show interfaces

IPV4インターフェース詳細

netsh interface ipv4 show interfaces [インデックス番号]

IPアドレス一覧表示

netsh interface ipv4 show addresses

ネットワーク設定

netsh interface ip set address [インターフェース名] static [IPアドレス] [サブネットマスク] [デフォルトゲートウェイ]

例：固定IP

netsh interface ip set address "ローカル エリア接続" static 192.168.3.5 255.255.255.0 192.168.3.1

例：dhcp

netsh interface ip set address "ローカル エリア接続" dhcp
netsh interface ip set dns "ローカル エリア接続" dhcp

インターフェース無効

netsh interface set interface "[インターフェース名]" disable

ワイヤレスLAN設定

「netsh wlan」はWiFiの設定ができるコマンドです。

接続設定

netsh wlan connect name="[SSID]"

接続設定(プロファイルの追加)

netsh wlan set profileparameter name="[SSID]" keymaterial=[セキュリティーキー] connectionmode=[auto/manual]

プロファイルをエクスポート

netsh wlan export profile name="[SSID]" folder=[出力先フォルダ]

プロファイルをインポート

netsh wlan add profile filename="[出力したxmlファイル]"

前回のつづき

リダイレクト、パイプ

標準出力と標準エラー出力

通常コマンドを入力し実行すると出力結果はモニタで確認できるようにコマンドプロンプトの画面上に出力されます。この出力結果のことは「標準出力」といいます。コマンドの文法が間違っている場合などエラーを伝える文章が表示された場合、通常の出力結果と違うため標準出力と区別します。そしてこの出力結果のことを「標準エラー出力」といいます。

実行結果の出力先

実行結果の出力先は通常ディスプレイになります。実はこの出力先はユーザーで自由に決めることができます。出力先をファイルにした場合はリダイレクトといい、出力先をほかのコマンドにする場合はパイプといいます。

ログ

出力結果をログとして残しておきたい場合はファイルにリダイレクトさせます。標準出力と標準エラー出力を別のファイルに分けることもできます。

リダイレクト

コマンドとファイルの間に大なり(>)を入れることでリダイレクトさせることができます。

[コマンド] > [ファイル]

通常の大なり(>)の場合は出力結果は上書きされますが、大なり大なり(>>)の場合は上書きされることなく追記することができます。
[コマンド] >> [ファイル]

パイプ

コマンドとコマンドの間に(|)を入れることでパイプすることができます。

[コマンド] | [コマンド]

例：リダイレクト、パイプ

@echo off

rem echoの出力内容をtest.txtにリダイレクト
echo Car > test.txt
echo Apple >> test.txt
echo Desk >> test.txt 
echo Bag >> test.txt

rem ファイルの表示内容をsortコマンドにパイプしさらに出力結果をresult.txtにリダイレクト
type test.txt | sort > result.txt

pause

結果

test.txt
Car
Apple
Desk
Bag

result.txt
Apple 
Bag
Car 
Desk

コマンドの結果を出力させない

コマンド  > nul

@echo off
net user | findstr /I guest > nul
pause

文字列の操作

プログラムでは特定の文字を切り出したり、文字を置き換えたりと文字列の操作を頻繁に行います。batでもこれらの操作行うためいろいろなコマンドが用意されています。

・文字列切り出し・置き換え
%[変数名]:~[開始位置],[文字数]%

%[変数名]:~m%  m文字目から、最後まで
%[変数名]:~m,n%    m文字目から、n文字分
%[変数名]:~m,-n%   m文字目から、最後のn文字分を除いたもの
%[変数名]:~-m% 後ろからm文字目から、最後まで
%[変数名]:~-m,n%   後ろからm文字目から、n文字分
%[変数名]:~-m,-n%  後ろからm文字目から、最後のn文字分を除いたもの
%[変数名]:a=b% 文字aを文字bに置換

日付/時刻

日付と時刻は形式がいろいろあり表記方法に悩むことがあります。
これを置き換えと切り出しを使ってどんな表記形式でも対応できるようにします。

@echo off
set date_tmp=%date:/=%
set time_tmp=%time: =0%
set yyyy=%date_tmp:~0,4%
set yy=%date_tmp:~2,2%
set mm=%date_tmp:~4,2%
set dd=%date_tmp:~6,2%
set hh=%time_tmp:~0,2%
set mi=%time_tmp:~3,2%
set ss=%time_tmp:~6,2%
echo %yyyy%-%mm%-%dd% %hh%:%mi%:%ss%
echo %yyyy%/%mm%/%dd% %hh%:%mi%:%ss%
pause

コマンドの出力結果から指定文字列を検索

findstr [オプション] "[指定文字列]" [検索対象ファイル]

よく使うオプション
/S: サブディレクトリを全部、再帰する。（シンボリックリンクも辿るかは未検証）
/I: アルファベットの大小文字を区別しない。（デフォだと区別する）
/X: 完全一致する行だけ。
/N: 行番号も表示する。（デフォだとファイル名だけ）

@echo off
net user | findstr /I guest
pause

ファイル操作

コピー

copy

copy [source_file] [destination_file]
低機能で単一のファイルのコピーに使う

xcopy

・xcopy [source_file] [destination_file]
copyより高機能。ファイルをディレクトリ構造ごとコピーできる

・よく使うオプション
/D:MM/DD/YYYY   指定した日付以降に更新されたファイルのみコピーする
/D  コピー先に同名のファイルが存在する場合に更新日が新しいファイルのみコピーする
/P  コピー前に確認メッセージを表示する
/S  ファイルが存在する場合のみコピーするサブディレクトリまで含めてディレクトリごとコピーする
/E  ファイルが存在しなくてもコピーするサブディレクトリまで含めてディレクトリごとコピーする
/EXCLUDE:file name  指定したファイルをコピー対象から外す（複数ファイル指定時は"+"でくくる）
/W  キー入力を待ってコピーを開始する
/C  コピー時のエラーを無視する
/I  コピー先のディレクトリが存在しない場合は新規にディレクトリを作成する
/Q  コピーしたファイル名を表示しない
/H  隠しファイルやシステムファイルも全てコピーする
/T  ファイルが存在するディレクトリのディレクトリのみコピーする
/O  ファイルの所有権やアクセス権限もそのままコピーする
/Y  同名のファイルが存在する場合、上書きの確認を行わない

@echo off
set source=%USERPROFILE%\Desktop\source
set destination=%USERPROFILE%\Desktop\destination

xcopy /S /C /I /Q /Y %source%\* %destination%

pause

robocopy

・robocopy [source_file] [destination_file]
主にバックアップに使う。フォルダの同期が可能。コピー元、コピー先の差分を確認してコピーすることが可能。

・よく使うオプション
/B  バックアップ専用の権限を持ったアカウント（バックアップモード）でファイルをコピーする
/MIR    ディレクトリツリーをミラー化する　増減両方の差分を反映する
/XO     古いファイルを除外する
/E      空のディレクトリを含むサブディレクトリをコピーする
/COPY:Flag  ファイルにコピーする情報を指定する(既定値は/COPY:DAT)
┣/COPY:DAT　既定値
┗/COPY:DATS　フォルダのアクセス権もコピー
/R:1    コピー失敗時に何回再試行 (Retry) するか。1 の場合は、失敗した後にもう一度だけ再試行する。
/W:1    コピー失敗と判断するまでの待ち時間 (Wait time)。
/LOG:FileName   ログファイルに状態を出力する（既存ファイルを上書く）
/LOG+:FileName  ログファイルに状態を出力する（既存ファイルに追記）
/NP     進捗非表示
/NFL    コピー成功時にはファイル名のログ出力しない
/NDL    コピー成功時にはフォルダ名のログを出力しない
/L      テストモード（ドライラン）。

@echo off
set source=%~dp0\source
set destination=%~dp0\destination

robocopy %source% %destination% /B /E /R:1 /W:1 /LOG:%destination%\log.txt /NP

pause

ファイルの移動や名前の変更

move [source_file] [destination_file]

・オプション
/Y  上書き時に確認しない
/-Y 上書き時に確認する

ディレクトリを作成する

mkdir [new directory name]

ディレクトリを削除する

rd [directory name]

・オプション
/s  ファイルやサブディレクトリも含めて削除する
/q  /sで削除する際に確認メッセージを表示しない

ファイルを削除

del [directory name]

・オプション
/P  ファイルの削除前に確認メッセージを表示する
/F  読み取り専用ファイルを削除する
/S  指定したファイルを全てのサブディレクトリから削除し、削除したファイル名を表示する
/Q  削除前に確認メッセージを表示しない

管理者権限を持っているかどうか

openfilesは使用中の共有ファイルを表示するコマンドだが、管理者権限の持ったユーザーのみ使用可能。
これを使って管理者権限をもっているか判断する。

@echo off
openfiles > NUL 2>&1 
if NOT "%ERRORLEVEL%" == "0" goto user
echo 【○】管理者権限です
goto END
:user
echo 【×】管理者権限ではありません。
:END
pause

次回はよく使うコマンドまとめです。
ユーザー操作、レジストリ操作、タスクスケジュールなど

バッチファイルとは

複数のコマンド処理を一つのファイルにまとめ、記述したコマンドを上から順に実行させるファイルのこと。ファイルの拡張子は.bat。

バッチファイルの作成方法

テキストファイルを作成し拡張子をbatに変更します。エディタでそのファイルを開き以下のコードを入力してください。

@echo off
echo HELLO WORLD
pause

作成したバッチファイルをダブルクリックで実行します。
コマンドプロンプトの画面にHELLO WORLDと表示されれば成功です。

プログラム解説

@echo off

一番初めに記載します。echoをオフにすると不要な実行コマンドが表示されなくなり画面が見やすくなります。

echo

設定した任意の文字列を表示するコマンドです。

echo [表示したい文字列]

pause

実行を一時停止されるコマンドです。

rem

バッチファイル内にコメントを記述することができるコマンドです。
コメントの部分にそのほかのコマンドを記述しても実行されることはありません

rem [コメント]

@echo off
rem echoコマンド
echo HELLO WORLD
rem echo 実行されない
pause

変数

変数はメモリに文字列などの値を保存するために使います。使い方は変数の名前を決めて、そこに保存する値を記述します。値を取り出したいときは%変数名%で取り出せます。変数はプログラムミングになくてはならないものです。使いこなせるようにしましょう。

batではsetコマンドを使って変数を設定します。

set 変数名=値

@echo off
rem 変数名aに「HELLO WORLD」(値)を保存
set a=HELLO WORLD

rem 変数から値を取り出し
echo %a%

pause

setのオプション

オプションとは通常のコマンドの処理になにか機能追加するためのものです。

/a オプション

文字列ではなく数字の加算時に使われます。

@echo off
set a=1
set /a a+=1
echo %a%
pause

結果
2

/p オプション

メッセージ付きでユーザーから標準入力を受け付けます。任意の入力を受け付ける場合時によく使用します。

@echo off
:NAME_SET
cls
ECHO +-------------------------------------------------------+
ECHO  名前を入力してください。
ECHO +-------------------------------------------------------+
SET /P NAME=">>"

if "%NAME%" == "" (
  echo 名前を入力してください。
  pause
  goto :NAME_SET
) else (
  echo あなたのお名前は %NAME% です。
)
pause

環境変数

初めからWindowsで設定されている変数のことです。例えばパソコンやユーザーごとで変わってしまうフォルダを参照する場合などで使われます。

よく使う環境変数

・カレントディレクトリ
%~dp0
・ユーザープロファイル
%USERPROFILE%
・コンピュータ名
%computername%

@echo off
echo カレントディレクトリ：%~dp0
echo ユーザープロファイル：%USERPROFILE%
pause

制御

バッチは上から順にコマンドを実行していくプログラムです。しかしこれだけでは簡単なものしか作成することができません。これをさらに複雑なものを作成するためにはプログラムにいろいろな流れを与え制御する必要があります。これを実現する方法にはif文を使った条件分岐とforを使った反復、サブルーチン、gotoを使った位置移動などがあります。

if文を使った条件分岐

条件を設定し条件に合格した場合はこの制御、不合格の場合はこの制御、といった場合に使用します。

if使い方

if 条件文 (
    合格した場合の制御内容
)

elseif使い方

if 条件文 (
    合格した場合の制御内容
) else (
    不合格した場合の制御内容
)

一行で書く場合

if 条件 合格した場合の制御内容 else 不合格した場合の制御内容

条件文の書き方

AとBが正しい場合

if A == B (

)

AとBが正しく無い場合

if not A == B (

)

数値比較

[数値1]と[数値2]が等しい

if [数値1] equ [数値2] (

)

[数値1]と[数値2]が等しくない

if [数値1] neq [数値2] (

)

[数値1]が[数値2]より小さい

if [数値1] lss [数値2] (

)

[数値1]が[数値2]以下

if [数値1] leq [数値2] (

)

[数値1]が[数値2]より大きい

if [数値1] gtr [数値2] (

)

[数値1]が[数値2]以上

if [数値1] geq [数値2] (

)

ファイルの有無

IF EXIST ファイル名 (

)

空判定

入力されたかどうか判定するときによく使います。

@echo off
set no=
if "%no%" == "" (
	echo 空
) else (
	echo 空ではない
)
pause

結果
空

※変数にダブルクォーテーションを囲わないと変数の未定義エラーになる。

文字列比較

入力した文字をチェックするときなどに使います。

@echo off
set str=テスト
if "%str%" == "テスト" (
	echo 【○】%str%
) else (
	echo 【×】%str%
)
pause

結果
【○】テスト

否定

@echo off
set str=テスト
if not "%str%" == "テスト" (
	echo 【○】%str%
) else (
	echo 【×】%str%
)
pause

結果
【×】テスト

ファイルの有無

ファイルが存在するかどうかのチェックで使います。

@echo off
set FILE=test.bat
IF EXIST "%FILE%" (
	echo %FILE%は存在する。
) else (
	echo %FILE%は存在しない。
)
pause

結果
test.batは存在する。

数値比較

@echo off

set a=1
set b=2
set c=1
set d=3

if %a% equ %c% echo %a%と%c%は等しい。
if %a% neq %b% echo %a%と%b%は等しくない。
if %a% lss %b% echo %a%は%b%より小さい。
if %a% leq %b% echo %a%は%b%以下。
if %d% gtr %b% echo %d%は%b%より大きい。
if %d% geq %b% echo %d%は%b%以上。
pause

結果

1と1は等しい。
1と2は等しくない。
1は2より小さい。
1は2以下。
3は2より大きい。
3は2以上。

反復・繰り返し制御

プログラムでは反復制御をよく使われます。同じことを繰り返すことは人間には難しいですが、機械は簡単にこなします。起動している間ずっと同じことをやり続けさせることもできるため自動化には欠かすことが出来ない制御です。batではファイルの中身を一行つづ取り出すときやファイルやフォルダを検索するときにこの処理をよく使います。

forを繰り返し制御

・基本型
下記が基本型になります。順を追って説明します。

FOR オプション %%アルファベット1文字 in (ループ処理の対象) do (

)

・オプション
オプションとは通常のコマンドの処理になにか機能追加するためのものです。これによりより細かいコマンドの処理を要求することができます。forにもありオプションを使うことでいろいろな制御が可能です。

(オプション無し) ディレクトリ内を対象にとる
/d ディレクトリ（フォルダ）名を対象にとる
/r ディレクトリ名及びそのサブディレクトリ内（そのフォルダの中のファイル名やフォルダ名）を対象にとる
/l 値を指定して代入する
/f テキストファイル内の文章に対してトークンを取り出して代入する

・%%アルファベット１文字
オプションが決定した処理の対象を変数に代入します。forのみ使用できる特別な変数になります。
※大文字と小文字は別物として判断
※変数はfor文の中でだけ有効

・ループ処理の対象
何回繰り返すかの場合は数字、フォルダやファイルの検索結果を対象にする場合はファイル名、テキスト内容やコマンドの出力結果を一行づつ取り出す場合はファイル名・コマンドなどがここに入ります。よってオプションによって内容が変わります。

指定した値まで繰り返す

ほかのプログラムでも良く使う処理です。オプション/lを使用します。

for /l %%アルファベット1文字 in (開始値、増加値、終了値) do (
    %%アルファベット1文字には繰り返され増加されている値が入る
)

0から10まで繰り返し

@echo off
for /l %%i in (0,1,10) do echo %%i
pause

ファイル検索

ここからbat特有の処理になります。フォルダ内からファイルやフォルダ名を検索するときにfor文を使います。フォルダ内のファイル名を一つ一つ調べていくため繰り返し処理が利用されています。

以下はデスクトップ内にある拡張子.batのファイルをすべてlog.txtに出力するプログラムです。ファイル名を対象にしますのでオプション/rを使用します。またフォルダ名のみ対象の場合はオプション/dを使用します。

for /r %%アルファベット1文字 in (検索対象) do (
    %%アルファベット1文字には検索対象のファイル名が入る
)

@echo off
cd %USERPROFILE%\Desktop
for /r %%A in (*.bat) do (
	if exist "%%A" (
		echo %%A >> log.txt
	)
)
pause

テキスト内の文章やコマンドの出力結果

コマンドの出力結果もfor文を使って一行づつ取り出しすことができます。コマンドを対象にしますのでオプション/Fを使用します。

FOR /F "トークンオプション" %%アルファベット1文字 in (ファイル名/'コマンド') do (
    テキストファイル内の文章に対してトークンを取り出して代入
)

・トークン（列番号）
for文で一行づつ文章を取り出します。文章には一行内にいろいろな意味を持たせるため列の概念を持っています。そのためどの列の値を取り出したいか指定するためトークンというオプションが利用できます。

name age address tel
tanaka 25 osaka 00-0000-0000
nakamura 26 nara 00-0000-0000


・トークンオプション一覧
tokens= 何番目のトークンを指定するか？
delims= トークンの区切り文字を指定(指定が無い場合はスペース)
eol= この文字から始まる行を無視
skip= 先頭から指定された行数、スキップする。データにタイトルなどある場合に使う。

テキスト内の文章から特定の列を取り出す。

@echo off
rem 検索用ファイルを作成
echo name age address tel > test.txt
echo tanaka 25 osaka 11-0000-0000 >> test.txt
echo nakamura 26 nara 22-0000-0000 >> test.txt
echo ito 27 kyoto 33-0000-0000 >> test.txt

FOR /F "tokens=2 skip=1" %%a in (test.txt) do (
	echo %%a
)
pause

コマンドの出力結果から特定の列を取り出す。

@echo off
FOR /F "tokens=2 skip=2 eol=-" %%a in ('net user') do (
	echo %%b
)
pause

2行目の値を取得する場合

2つ以上のトークンを指定したとき、2つ目以降のトークンは定義したアルファベットの次の文字に代入される。

@echo off
FOR /F "usebackq tokens=1,2 skip=2 eol=-" %%a in ('net user') do (
	if not "%%b" == "" echo %%b
)
pause

%%aが定義されているので2列目の値は%%bに代入される。

%%a 1列目
%%b 2列目
%%c 3列目

その他のトークンの指定例

・全ての列
tokens=*

・2列目とそれ以降すべて
tokens=2,*

setlocal enabledelayedexpansion

変数を定義した後にif,for文などのカッコ内に定義した変数の値を変更しても初めに定義した値から書き換わらない現象に対応するために遅延環境変数を使う。遅延環境変数を使うためにこの一文を追加する必要がある。そして変数は%で囲うのではなく！で囲う。

遅延環境変数を使わない場合

@echo off
set a=1
echo %a%

if 1 == 1 (
  set /a a+=1
  echo %a%
)
pause

結果
1
1

遅延環境変数使った場合

@echo off
setlocal enabledelayedexpansion

set a=1
echo %a%
if 1 == 1 (
  set /a a+=1
  echo !a!
)
pause

結果
1
2

位置移動

goto

指定したラベルの位置に処理を移動させます。

・基本型
GOTO ラベル名

:ラベル名

@echo off
set a=0

:start
echo 処理開始 
goto :work

:work
echo 処理中
set /a a+=1
goto :end

:end
echo %a%:処理終了
if %a% == 10 (
    goto :exit
)

goto :start

:exit
echo 処理数が10に到達したので処理を終了

pause

サブルーチン

サブルーチンとは中核の処理とは別にほかの処理から呼び出されて処理を行うプログラムのことをいいます。batではcallがそれにあたります。gotoのようにラベルを設定しcallでラベルに移動します。gotoでは移動後もとの位置には戻りませんが、callは元の位置に戻ります。サブルーチンは引数を持っていて呼び出しもとの処理から値を受け取ることができます。受け取った値を処理して元の処理に渡すこともできます。ほかのプログラムの関数のように使用することができます。

@echo off
set /P a="数字を入力してください>>"
call :sub %a%
echo %a%
pause
rem サブルーチン
:sub
rem 受け取った値に100足す
set /a a=%1+100

rem 処理した値を返す
exit /b %a%

・call
batの実行、サブルーチンの実行

・exitとexit /b
exit
処理を止めて終了させる

・exit /b 戻り値
サブルーチンに引数を渡す

バッチの基本制御はここまで。
次回はリダイレクト、パイプ、文字列の操作、ファイルの操作、よく使うコマンドなどをまとめていきます。

SCPコマンドはリモートのマシンにデータをコピーするコマンドです。コピーコマンドのcpにsがついています。
sはSSHのsで内部的にSSHを使用しているため盗聴されずに安全にデータをコピーすることができます。
しかしWindwosでは標準で実装されておらず使用するためにはツールをインストールする必要があります。
そこで今回比較的に容易に使用できるツールを2つ紹介します。

Git BushでSCPコマンドを使う

これをインストールするとWindowsでLinuxのコマンド(Bush)が利用できます。このツールを使いSCPコマンドを使用します。

ツールをダウンロードします。
https://gitforwindows.org/
ダウンロードしたファイルを実行します。

基本的にインストール画面ではすべて「next」でOKです。

これでインストール完了です。
アプリケーションから「Git Bush」を起動します。コマンドプロンプトのような画面からSCPコマンドを入力し使用します。

TeraTermを使用してSCPを使う

SSHクライアントアプリケーションのTeraTermでもSCPを使用することができます。

ではTeraTermをダウンロードします。

https://forest.watch.impress.co.jp/library/software/utf8teraterm/

これでインストール完了です。

TeraTermを起動して「ファイル→SSH SCP」をクリックします。

表示された画面からリモートマシンにデータコピーしたり、PCにデータをダウンロードすることができます。

ウェブの入力フォームのようにWindowsのバッチで再現します。再現するためには入力を受け付ける「SET /P」と画面遷移のように確認→完了を再現するために「GOTO:」を使用します。

SET /P 変数=”メッセージ”

任意の入力を受け付ける場合は「SET /P」を使用します。
 
使用例

REM 初期化
SET INPUTSTR=
SET /P INPUTSTR="入力してください。"

GOTO:

確認や完了のメッセージの処理へ移動させるために使います。
 
使用例
 

:INPUT_CHECK
SET INPUTSTR=
SET /P INPUTSTR="入力してください。
IF "%INPUTSTR%"=="" GOTO :INPUT_CHECK
ECHO 完了

文字入力→確認→完了

「SET /P」「GOTO」を使って任意の文字入力→確認→完了 を完成させます。 以下がサンプルコードになります。
 

@ECHO OFF

:INPUT_START
ECHO +-------------------------------------------------------+
ECHO  文字を入力してください。
ECHO +-------------------------------------------------------+
SET INPUT_STR=
SET /P INPUT_STR=

IF "%INPUT_STR%"=="" GOTO :INPUT_START

:INPUT_CONF
ECHO +-------------------------------------------------------+
ECHO  入力した文字は[%INPUT_STR%]でよろしいですか？
ECHO （Y / N）
ECHO +-------------------------------------------------------+
SET CONF_SELECT=
SET /P CONF_SELECT=

IF "%CONF_SELECT%"== SET CONF_SELECT=Y
IF /I NOT "%CONF_SELECT%"=="Y"  GOTO :INPUT_START

:INPUT_END
ECHO +-------------------------------------------------------+
ECHO  完了しました。
ECHO +-------------------------------------------------------+

PAUSE
EXIT

 
起動すると